Batch Grundkurs 002: Ordner automatisch erstellen

Worum geht es in diesem Teil?

In diesem zweiten Teil des Batch-Grundkurses erstellen wir automatisch mehrere Ordner mit einer Batchdatei.

Das ist ein sehr typischer Anwendungsfall im Office- und Projektalltag. Oft braucht man immer wieder dieselbe Ordnerstruktur, zum Beispiel für neue Projekte, Videos, Downloads, Grafiken, Audio-Dateien, Backups oder Exportdateien.

Statt diese Ordner jedes Mal manuell im Explorer anzulegen, kann eine Batchdatei das automatisch erledigen.

In diesem Teil gibt es zwei Varianten:

• eine einfache Variante, die Ordner im aktuellen Ordner erstellt
• eine SendTo-Variante, die eine Ordnerstruktur in einem übergebenen Ordner erstellt

Warum ist dieses Beispiel praktisch?

Beim Arbeiten mit Projekten entsteht oft eine ähnliche Struktur. Zum Beispiel:

01_Rohmaterial
02_Audio
03_Projektdateien
04_Grafiken
05_Export
06_Thumbnail
07_Backup

Solche Ordner kann man natürlich manuell erstellen. Sobald man das aber regelmäßig macht, lohnt sich ein kleines Skript.

Dieses Beispiel zeigt sehr schön, wie Batchdateien einfache Routineaufgaben übernehmen können. Es ist immer noch leicht verständlich, hat aber schon einen echten praktischen Nutzen.

Hinweis zur Kursreihe

Dieses Skript ist Teil einer größeren Vergleichsreihe. Die Aufgabe wird zuerst mit Batch umgesetzt. Später folgen passende Varianten mit PowerShell 7 und Python, damit man die unterschiedlichen Lösungswege direkt miteinander vergleichen kann.

Batch        = einfacher Einstieg mit Windows-Bordmitteln
PowerShell 7 = moderner und leistungsfähiger für Windows-Automatisierung
Python       = sehr flexibel und auch für größere Tools geeignet

Downloads zu diesem Teil

Für diesen Teil gibt es zwei Downloads: die Batchdateien für diesen Kursteil und die gemeinsame Testumgebung für die Windows-Automatisierung.

C:\TOPTORIALS_CODE\000_Batch_Grundkurs

C:\TOPTORIALS_CODE\000_Batch_Grundkurs\002_Ordner_erstellen

C:\TOPTORIALS_CODE\1000_TESTBEREICH

TOPTORIALS_Testdaten_Windows_Automatisierung_Batch_V001

Testumgebung zum Mitmachen

Für diese Tutorialreihe gibt es eine vorbereitete Testumgebung. Damit kannst du die Batchdateien gefahrlos ausprobieren, ohne eigene wichtige Dateien verwenden zu müssen.

Die Testumgebung ist sprachübergreifend aufgebaut. Das bedeutet: Die gleiche Grundstruktur kann später auch für die passenden PowerShell-7- und Python-Versionen verwendet werden. Dadurch lassen sich die unterschiedlichen Lösungen besser miteinander vergleichen.

Empfohlener Speicherort für die ZIP-Datei:

C:\TOPTORIALS_CODE\1000_TESTBEREICH

Wenn du die ZIP-Datei dort entpackst, entsteht zunächst dieser Ordner:

C:\TOPTORIALS_CODE\1000_TESTBEREICH\TOPTORIALS_Testdaten_Windows_Automatisierung_V001

Für den Batch-Grundkurs benennen wir diesen entpackten Ordner um in:

TOPTORIALS_Testdaten_Windows_Automatisierung_Batch_V001

Danach sieht der Pfad zum Testdatenordner für den Batch-Grundkurs zum Beispiel so aus:

C:\TOPTORIALS_CODE\1000_TESTBEREICH\TOPTORIALS_Testdaten_Windows_Automatisierung_Batch_V001

Für diesen Teil verwendest du dann den passenden Unterordner:

C:\TOPTORIALS_CODE\1000_TESTBEREICH\TOPTORIALS_Testdaten_Windows_Automatisierung_Batch_V001\002_Ordner_erstellen

Der Vorteil dieser Struktur ist, dass die allgemeine ZIP-Datei neutral bleibt, aber jeder Kurs seine eigene Arbeitskopie bekommt:

TOPTORIALS_Testdaten_Windows_Automatisierung_Batch_V001
TOPTORIALS_Testdaten_Windows_Automatisierung_PowerShell7_V001
TOPTORIALS_Testdaten_Windows_Automatisierung_Python_V001

Du musst die Testumgebung aber nicht verwenden. Die Batchdateien funktionieren auch mit eigenen Ordnern. Wichtig ist nur, dass du zuerst mit Testordnern arbeitest und nicht direkt mit wichtigen Originaldateien.

Sicherheitshinweis

Dieses zweite Skript ist noch relativ ungefährlich, weil es keine Dateien löscht, verschiebt oder umbenennt. Es erstellt nur Ordner, die noch nicht vorhanden sind.

Enthaltene Skripte

Zu diesem Teil gehören zwei Batchdateien:

002_ordner_erstellen.bat
002_sendto_projektordner_erstellen.bat

Variante 1: Ordner im aktuellen Ordner erstellen

Die Datei 002_ordner_erstellen.bat wird direkt in dem Ordner gestartet, in dem die neue Ordnerstruktur erstellt werden soll.

Wenn das Skript zum Beispiel in diesem Ordner liegt:

C:\TOPTORIALS_CODE\TESTBEREICH\Projekt_001

dann erstellt es dort die festgelegten Unterordner.

Wenn du die vorbereitete Testumgebung verwendest, kannst du diese Variante zum Beispiel im Ordner für Teil 002 testen:

C:\TOPTORIALS_CODE\1000_TESTBEREICH\TOPTORIALS_Testdaten_Windows_Automatisierung_Batch_V001\002_Ordner_erstellen

Kopiere die Datei 002_ordner_erstellen.bat in einen passenden Testordner und starte sie per Doppelklick. Danach sollten die Standardordner dort automatisch erstellt werden.

Erstellte Ordner

Das Skript erstellt folgende Ordner:

01_Rohmaterial
02_Audio
03_Projektdateien
04_Grafiken
05_Export
06_Thumbnail
07_Backup
08_UmlauttestäöüßÄÖÜ

Der letzte Ordner mit Umlauten dient hier zusätzlich als Test, ob Umlaute in Ordnernamen korrekt verarbeitet werden.

Der komplette Code der einfachen Variante

@echo off
REM ============================================================
REM TOPTORIALS OFFICE - Batch Grundkurs
REM Script: 002_ordner_erstellen.bat
REM Beschreibung: Erstellt eine feste Standardordnerstruktur im aktuellen Ordner.
REM Autor: Chris
REM YouTube: https://www.youtube.com/@TOPTORIALS-OFFICE
REM Webseite: https://www.toptorials.com
REM Version: 1.0
REM Stand: 2026-06-27
REM ============================================================
echo.
:: Ändert die Codepage auf UTF-8
chcp 65001 >nul

::Ändert die Codepage auf Windows-1252 (ANSI)
::chcp 1252 >nul

echo Standardordner werden erstellt...
echo.

if not exist "01_Rohmaterial" mkdir "01_Rohmaterial"
if not exist "02_Audio" mkdir "02_Audio"
if not exist "03_Projektdateien" mkdir "03_Projektdateien"
if not exist "04_Grafiken" mkdir "04_Grafiken"
if not exist "05_Export" mkdir "05_Export"
if not exist "06_Thumbnail" mkdir "06_Thumbnail"
if not exist "07_Backup" mkdir "07_Backup"
if not exist "08_UmlauttestäöüßÄÖÜ" mkdir "08_UmlauttestäöüßÄÖÜ"

echo.
echo Fertig.
echo.
pause

Code der einfachen Variante erklärt

@echo off

@echo off

Diese Zeile sorgt wieder dafür, dass die Befehle selbst nicht im Fenster angezeigt werden. Dadurch wirkt die Ausgabe im Konsolenfenster sauberer und verständlicher.

Kommentarblock mit REM

REM ============================================================
REM TOPTORIALS OFFICE - Batch Grundkurs
REM Script: 002_ordner_erstellen.bat
REM Beschreibung: Erstellt eine feste Standardordnerstruktur im aktuellen Ordner.
REM Autor: Chris
REM YouTube: https://www.youtube.com/@TOPTORIALS-OFFICE
REM Webseite: https://www.toptorials.com
REM Version: 1.0
REM Stand: 2026-06-27
REM ============================================================

Der Kommentarblock beschreibt das Skript. Er wird nicht ausgeführt, sondern dient nur zur Orientierung.

Gerade wenn man viele Skripte sammelt oder weitergibt, ist so ein Kopfbereich sehr hilfreich. Man sieht sofort, wofür das Skript gedacht ist, von wem es stammt und welche Version man vor sich hat.

echo.

echo.

Mit echo. wird eine leere Zeile ausgegeben. Das verbessert nur die Lesbarkeit im Fenster.

chcp 65001 >nul

chcp 65001 >nul

Mit chcp wird die Codepage der Eingabeaufforderung geändert. Die Codepage beeinflusst, wie bestimmte Zeichen dargestellt werden.

65001 steht für UTF-8. Das ist vor allem dann interessant, wenn Umlaute oder Sonderzeichen in der Batchdatei oder in Ordnernamen vorkommen.

Das >nul sorgt dafür, dass die Ausgabe dieses Befehls nicht im Fenster angezeigt wird. Ohne >nul würde Windows eine zusätzliche Meldung zur aktiven Codepage ausgeben.

Alternative Codepage als Kommentar

::Ändert die Codepage auf Windows-1252 (ANSI)
::chcp 1252 >nul

Diese beiden Zeilen beginnen mit :: und sind dadurch in diesem Zusammenhang als Kommentar gedacht.

Die zweite Zeile wäre eine Alternative zu UTF-8. 1252 steht für Windows-1252, also eine klassische Windows-Codepage für westeuropäische Zeichen.

Weil die Zeile auskommentiert ist, wird sie nicht ausgeführt.

Startmeldung ausgeben

echo Standardordner werden erstellt...
echo.

Diese Zeilen geben eine kurze Information im Fenster aus. So sieht man beim Start direkt, was das Skript gerade macht.

Prüfen und Ordner erstellen

if not exist "01_Rohmaterial" mkdir "01_Rohmaterial"

Das ist die wichtigste Zeile in diesem Skript.

Sie besteht aus zwei Teilen:

• if not exist "01_Rohmaterial" prüft, ob der Ordner noch nicht existiert.
• mkdir "01_Rohmaterial" erstellt den Ordner.

Die Zeile bedeutet also:

Wenn der Ordner 01_Rohmaterial noch nicht existiert,
dann erstelle ihn.

Das ist sicherer, als einfach blind einen Ordner anzulegen. Wenn der Ordner bereits vorhanden ist, passiert nichts.

Dasselbe Prinzip wird für alle weiteren Ordner wiederholt:

if not exist "02_Audio" mkdir "02_Audio"
if not exist "03_Projektdateien" mkdir "03_Projektdateien"
if not exist "04_Grafiken" mkdir "04_Grafiken"
if not exist "05_Export" mkdir "05_Export"
if not exist "06_Thumbnail" mkdir "06_Thumbnail"
if not exist "07_Backup" mkdir "07_Backup"
if not exist "08_UmlauttestäöüßÄÖÜ" mkdir "08_UmlauttestäöüßÄÖÜ"

Warum stehen die Ordnernamen in Anführungszeichen?

Die Ordnernamen stehen in Anführungszeichen, zum Beispiel:

"03_Projektdateien"

Das ist eine gute Gewohnheit. Wenn später ein Ordnername Leerzeichen enthält, bleibt der Befehl trotzdem korrekt.

Beispiel:

if not exist "Alte Dateien" mkdir "Alte Dateien"

Ohne Anführungszeichen könnte Windows den Ordnernamen falsch interpretieren.

Fertigmeldung und Pause

echo.
echo Fertig.
echo.
pause

Am Ende gibt das Skript eine kurze Fertigmeldung aus.

pause sorgt dafür, dass das Fenster offen bleibt, bis eine Taste gedrückt wird. Ohne pause würde sich das Fenster nach einem Doppelklick oft sofort wieder schließen.

Variante 2: Ordnerstruktur per SendTo erstellen

Die zweite Datei heißt:

002_sendto_projektordner_erstellen.bat

Diese Variante ist für das Windows-Menü Senden an gedacht.

Damit kann man im Explorer einen Ordner markieren und die Batchdatei über Rechtsklick > Senden an verwenden. Die Ordnerstruktur wird dann nicht dort erstellt, wo die Batchdatei liegt, sondern in dem Ordner, der an das Skript übergeben wurde.

Wenn du die vorbereitete Testumgebung verwendest, kannst du für diese Variante ebenfalls einen Ordner aus dem Bereich für Teil 002 verwenden:

C:\TOPTORIALS_CODE\1000_TESTBEREICH\TOPTORIALS_Testdaten_Windows_Automatisierung_Batch_V001\002_Ordner_erstellen

Markiere dort einen passenden Testordner im Explorer und übergib ihn per Rechtsklick > Senden an an die SendTo-Batchdatei. Die Projektordner werden dann innerhalb des markierten Ordners erstellt.

Wofür ist die SendTo-Variante nützlich?

Die SendTo-Variante ist besonders praktisch, wenn man nicht jedes Mal die Batchdatei in den Zielordner kopieren möchte.

Man kann die Batchdatei oder eine Verknüpfung davon in den SendTo-Ordner legen und danach beliebige Projektordner im Explorer damit vorbereiten.

SendTo-Ordner öffnen

Den Windows-SendTo-Ordner öffnet man über:

shell:sendto

Dort kann man die Batchdatei oder eine Verknüpfung zur Batchdatei ablegen.

Der komplette Code der SendTo-Variante

@echo off
REM ============================================================
REM TOPTORIALS OFFICE - Batch Grundkurs
REM Script: 002_sendto_projektordner_erstellen.bat
REM Beschreibung: Erstellt eine Creator-Ordnerstruktur in einem uebergebenen Ordner.
REM Autor: Chris
REM YouTube: https://www.youtube.com/@TOPTORIALS-OFFICE
REM Webseite: https://www.toptorials.com
REM Version: 1.0
REM Stand: 2026-06-27
REM ============================================================
echo.
:: Ändert die Codepage auf UTF-8
chcp 65001 >nul

if "%~1"=="" (
    echo Bitte uebergib einen Ordner.
    echo.
    echo Du kannst zum Beispiel einen Ordner auf diese Batch-Datei ziehen
    echo oder Rechtsklick - Senden an verwenden.
    echo.
    pause
    exit /b
)

if not exist "%~1\" (
    echo Der uebergebene Pfad ist kein Ordner:
    echo %~1
    echo.
    pause
    exit /b
)

set "ZIEL=%~1"

echo Creator-Ordnerstruktur wird erstellt in:
echo %ZIEL%
echo.

if not exist "%ZIEL%\01_Rohmaterial" mkdir "%ZIEL%\01_Rohmaterial"
if not exist "%ZIEL%\02_Audio" mkdir "%ZIEL%\02_Audio"
if not exist "%ZIEL%\03_Projektdateien" mkdir "%ZIEL%\03_Projektdateien"
if not exist "%ZIEL%\04_Grafiken" mkdir "%ZIEL%\04_Grafiken"
if not exist "%ZIEL%\05_Export" mkdir "%ZIEL%\05_Export"
if not exist "%ZIEL%\06_Thumbnail" mkdir "%ZIEL%\06_Thumbnail"
if not exist "%ZIEL%\07_Backup" mkdir "%ZIEL%\07_Backup"
if not exist "%ZIEL%\08_UmlauttestäöüßÄÖÜ" mkdir "%ZIEL%\08_UmlauttestäöüßÄÖÜ"

echo.
echo Fertig.
echo.
pause

Code der SendTo-Variante erklärt

Prüfen, ob ein Ordner übergeben wurde

if "%~1"=="" (
    echo Bitte uebergib einen Ordner.
    echo.
    echo Du kannst zum Beispiel einen Ordner auf diese Batch-Datei ziehen
    echo oder Rechtsklick - Senden an verwenden.
    echo.
    pause
    exit /b
)

%~1 steht für den ersten übergebenen Parameter.

Bei einer SendTo-Batchdatei ist das normalerweise die Datei oder der Ordner, den man im Explorer markiert und an das Skript sendet.

Diese Prüfung bedeutet:

Wenn nichts übergeben wurde,
zeige einen Hinweis an und beende das Skript.

exit /b beendet die Batchdatei.

Prüfen, ob der übergebene Pfad wirklich ein Ordner ist

if not exist "%~1\" (
    echo Der uebergebene Pfad ist kein Ordner:
    echo %~1
    echo.
    pause
    exit /b
)

Diese Prüfung stellt sicher, dass der übergebene Pfad ein Ordner ist.

Der Backslash am Ende ist wichtig:

%~1\

Dadurch wird gezielt geprüft, ob es sich um einen Ordnerpfad handelt.

Wenn kein gültiger Ordner übergeben wurde, zeigt das Skript eine Meldung an und beendet sich.

Zielordner in einer Variable speichern

set "ZIEL=%~1"

Mit set wird eine Variable gesetzt.

In diesem Fall wird der übergebene Ordner in der Variable ZIEL gespeichert.

Dadurch muss man später nicht immer wieder %~1 schreiben, sondern kann mit dem besser lesbaren Namen %ZIEL% arbeiten.

Die Schreibweise

set "ZIEL=%~1"

ist eine bewährte Form, weil sie unerwünschte Leerzeichen am Ende der Variable vermeidet.

Zielordner anzeigen

echo Creator-Ordnerstruktur wird erstellt in:
echo %ZIEL%
echo.

Diese Zeilen zeigen an, in welchem Ordner die neue Ordnerstruktur erstellt wird.

Das ist besonders bei SendTo-Skripten sinnvoll, weil das Skript selbst an einem anderen Ort liegen kann als der Zielordner.

Ordner im übergebenen Zielordner erstellen

if not exist "%ZIEL%\01_Rohmaterial" mkdir "%ZIEL%\01_Rohmaterial"

Diese Zeile funktioniert ähnlich wie in der einfachen Variante, nur dass jetzt der Zielordner davor gesetzt wird.

Das bedeutet:

Wenn der Ordner 01_Rohmaterial im übergebenen Zielordner
noch nicht existiert, dann erstelle ihn dort.

Dasselbe passiert für die weiteren Ordner:

if not exist "%ZIEL%\02_Audio" mkdir "%ZIEL%\02_Audio"
if not exist "%ZIEL%\03_Projektdateien" mkdir "%ZIEL%\03_Projektdateien"
if not exist "%ZIEL%\04_Grafiken" mkdir "%ZIEL%\04_Grafiken"
if not exist "%ZIEL%\05_Export" mkdir "%ZIEL%\05_Export"
if not exist "%ZIEL%\06_Thumbnail" mkdir "%ZIEL%\06_Thumbnail"
if not exist "%ZIEL%\07_Backup" mkdir "%ZIEL%\07_Backup"
if not exist "%ZIEL%\08_UmlauttestäöüßÄÖÜ" mkdir "%ZIEL%\08_UmlauttestäöüßÄÖÜ"

Wie wird das Skript gestartet?

Einfache Variante

1. Die Datei 002_ordner_erstellen.bat in den gewünschten Zielordner kopieren.
2. Die Batchdatei per Doppelklick starten.
3. Die Ordnerstruktur wird im aktuellen Ordner erstellt.

SendTo-Variante

1. Die Datei 002_sendto_projektordner_erstellen.bat oder eine Verknüpfung davon in den SendTo-Ordner legen.
2. Den SendTo-Ordner mit shell:sendto öffnen.
3. Im Explorer einen Zielordner markieren.
4. Rechtsklick auf den Ordner.
5. Senden an auswählen.
6. Das Skript auswählen.
7. Die Ordnerstruktur wird im übergebenen Ordner erstellt.

Was passiert, wenn die Ordner schon vorhanden sind?

Das Skript prüft vor jedem mkdir-Befehl, ob der jeweilige Ordner bereits existiert.

Wenn der Ordner schon vorhanden ist, wird er nicht neu erstellt und nicht verändert.

Dadurch kann man das Skript auch mehrfach ausführen, ohne dass vorhandene Ordner überschrieben oder gelöscht werden.

Gibt es einen Testmodus?

Bei diesem Skript gibt es keinen speziellen _test-Modus.

Der Grund ist einfach: Das Skript erstellt nur Ordner, die noch nicht vorhanden sind. Es löscht nichts, verschiebt nichts und überschreibt keine Dateien.

Trotzdem sollte man auch dieses Skript zuerst in einem Testordner ausprobieren.

Typische Anpassungen

Die Ordnerstruktur kann direkt im Skript angepasst werden.

Wenn man zum Beispiel einen weiteren Ordner erstellen möchte, kann man einfach eine weitere Zeile hinzufügen:

if not exist "09_Notizen" mkdir "09_Notizen"

In der SendTo-Variante müsste die entsprechende Zeile so aussehen:

if not exist "%ZIEL%\09_Notizen" mkdir "%ZIEL%\09_Notizen"

Man kann die Ordnernamen natürlich auch komplett ändern.

Häufige Fehler

Die Datei wird nur im Editor geöffnet

Dann wurde sie wahrscheinlich als .txt-Datei gespeichert.

Die Datei muss wirklich zum Beispiel so heißen:

002_ordner_erstellen.bat

und nicht:

002_ordner_erstellen.bat.txt

Die SendTo-Variante meldet, dass kein Ordner übergeben wurde

Dann wurde das Skript vermutlich direkt per Doppelklick gestartet.

Die SendTo-Variante erwartet einen übergebenen Ordner. Sie sollte also entweder über Senden an verwendet werden oder man zieht einen Ordner auf die Batchdatei.

Die Umlaute werden falsch angezeigt

Bei Batchdateien können Umlaute je nach Speicherung der Datei und verwendeter Codepage problematisch sein.

In diesem Skript wird mit

chcp 65001 >nul

auf UTF-8 umgestellt. Trotzdem sollte man beim Speichern der Batchdatei darauf achten, dass die Datei passend gespeichert wird.

Für besonders robuste Skripte kann es manchmal sinnvoll sein, Umlaute in Ordnernamen zu vermeiden oder ae, oe, ue und ss zu verwenden.

Was haben wir gelernt?

In diesem Teil wurden mehrere wichtige Grundlagen gezeigt:

mkdir erstellt Ordner.
if not exist prüft, ob etwas noch nicht vorhanden ist.
Anführungszeichen schützen Pfade mit Leerzeichen.
%~1 steht für einen übergebenen Parameter.
set speichert Werte in Variablen.
SendTo-Skripte können mit markierten Ordnern aus dem Explorer arbeiten.
chcp kann die Codepage der Eingabeaufforderung ändern.

Damit ist aus dem einfachen Hello-World-Beispiel bereits ein kleines praktisches Werkzeug geworden, mit dem man Projektordner automatisch vorbereiten kann.

Video zu diesem Tutorial:

Das könnte Dich auch interessieren

Keine Einträge gefunden